Nate Holt

AutoCAD Electrical Etcetera

Wed, 26 Aug 2009 23:09:00 -0700

Controlling the Machine is no longer being updated. Don't worry, though, you can still follow Nate Holt at his new blog, AutoCAD Electrical Etcetera. You'll find it at http://nateholt.wordpress.com. Or you subscribe to his feed to get his latest words of wisdom automatically: http://nateholt.wordpress.com/feed/. You also can continue to view the Controlling Machine archives for Nate's AutoCAD Electrical tips and tricks.

Nate's Blog is Moving

Sun, 12 Jul 2009 17:21:00 -0700

Follow Nate’s AutoCAD Electrical blog as it prepares to move over into the “Peer” blogs section. Follow this the new link: http://nateholt.wordpress.com (RSS feed at http://nateholt.wordpress.com/feed ). The blog name is changing to "AutoCAD Electrical Etcetera". See you there! - Nate.

Update: ~~6 7 8 10 12 14 15~~ 17 new postings at this new blog site - most recent dealing with Circuit Builder!

Attribute writes to non-opened drawings

Mon, 06 Jul 2009 01:57:00 -0700

This dovetails with the last posting... instead of Xdata writes, this one illustrates attribute writes... find/replace block insert attribute values on non-opened drawings.

There is at least one other posting from a couple years ago ( ! ) that deals with this subject, but here we'll pull it together a bit more completely. We'll illustrate two little AutoLisp utilities... one that works on the active drawing only and employs straight, generic AutoLisp calls. The second will be a version that is meant to work on non-opened drawing files. It seems to test okay using AutoCAD Electrical 2008 through 2010. I did not test on other ACE versions, so exercise caution.

The Scenario

The example will be this... we want to post-process our electrical schematic drawings and look for block insert instances with attribute tag "COLOR". We examine the current value on the attribute. If it matches up with a short list of possible values, we map a new value to it and push this out to the attribute.

For example, if we find attribute "COLOR" with a value of "R" (for "red"), we want to map a new value of "RD" and push it out to the block insert's COLOR attribute. If we find a value of "G" (for "green"), we want to map a new value of "GN" and push it out.

The Straight AutoLISP version - active drawing only

Here is the first version of the utility (below). It is designed to process the active drawing only. You APPLOAD the utility, launch it at the "Command:" prompt. It runs, makes the changes, and exits.

(defun c:remap_color_attrval ( / ss en ix str target_attrnam maplst slen

              ben blknam enn edd oldval newval newedd hitattr hdl ed x)

; Process all block inserts on active drawing. Look for attribute

; named "COLOR". If found, check existing value and map new color

; value to it. Also adjust the attribute's text size a bit to

; accommodate the longer mapped attribute value (ex: change "R" to "RD"

; or change "B" to "BU")

;

; -- list mapping here --

(setq target_attrnam "COLOR")

(setq maplst (list

      (list "R" "RD") ; red

      (list "B" "BL") ; blue

      (list "A" "AM") ; amber

      (list "G" "GN") ; green

      (list "C" "CL") ; clear

      (list "W" "WT") ; white

) )

; -- main program starts here --

(setq ss (ssget "_X" '((0 . "INSERT"))))

(if (/= ss nil)

    (progn

      (setq slen (sslength ss)) ; number of entities in selection set

      (setq ix 0) ; use to index through the selection set list

      (while (< ix slen)

        (setq ben (ssname ss ix)) ; get next block insert instance

                                  ; from the selection set

        (setq ix (1+ ix)) ; increment index for next time

        ; Now look for target attribute tag. Can do this in either

        ; of two way... can use a call to look for the attribute on

        ; this block insert, or can do it the hard way and cycle

        ; through all stand-alone subentities of this block insert

        ; instance and look for the target attribute. Let's do it

        ; the hard way.



        ; Now cycle through its stand-alone subentities like attributes

        ; (this is not the same as cycling through the entities of the

        ; block definition itself)

        (setq hitattr nil)

        (if (setq enn (entnext ben)) (setq edd (entget enn)))

        (while (AND enn (not hitattr)

                        (/= (cdr (assoc 0 edd)) "SEQEND") ; end of this entity

                        (/= (cdr (assoc 0 edd)) "INSERT") ) ; beginning of next!

          (if (= (cdr (assoc 2 edd)) target_attrnam)

            (progn ; yes, found target attribute tag

              (setq oldval (cdr (assoc 1 edd)))

              (setq hitattr 1) ; remember that we've found target attribute

                           ; so we can exit out of the "while" loop

                           ; sooner rather than later.

              ; Look for this target value in the map list

              (setq newval nil) ; use as flag to remember if mapped value hit

              (foreach x maplst

                (if (= (car x) oldval)

                  (progn ; match on old attribute value

                    (setq newval (cadr x)) ; get the new mapped value

              ) ) )

              (if newval

                (progn ; yes, found a new mapped value for this attribute

                  ; Prepare to push new value back out to the attribute

                  (if (setq newedd (subst (cons 1 newval)(assoc 1 edd) edd))

                    (progn

                      (entmod newedd) ; push new attribute value out

                      ; Display something to the command window

                      (setq ed (entget ben)) ; open the block insert instance

                      ; Get block name

                      (setq blknam (cdr (assoc 2 ed)))

                      ; Get handle

                      (setq hdl (cdr (assoc 5 ed)))

                      ; Display to command window

                      (princ "\nHDL=")(princ hdl)

                      (princ " BLKNAM=")(princ blknam)

                      (princ ", ")(princ target_attrnam)

                      (princ " old=")(princ oldval)

                      (princ ", new=")(princ newval)

                  ) )

              ) )

          ) )

          (if (setq enn (entnext enn)) ; advance to next sub-entity of this

            (setq edd (entget enn)))   ; block insert instance

        )

      )

      (setq ss nil) ; release the selection set

) )

(princ)

)

The above can be downloaded here:

files/29401_29500/29471/file_29471.lsp - rename to remap_color_value.lsp. Appload it. Type remap_color_attrval [Enter] at the "Command:" prompt.

The second version - meant to operate on non-opened drawing files

This version parallels the one above but uses calls that are specific to AutoCAD Electrical (tested in ACE2008-2010 only). It is a bit longer and not reproduced here. Download a copy at this link:

files/29401_29500/29481/file_29481.lsp - rename to remap_color_value_notactive.lsp. Appload it. Type remap_color_attrval_projectwide [Enter] at the "Command:" prompt.

The advantage of this second version is that the processing can be done on multiple drawings without having to open each in turn.

Pushing Xdata out to non-opened AutoCAD Electrical drawings

Mon, 22 Jun 2009 03:21:00 -0700

A user's custom application needed a little performance boost. Opening and closing multiple drawings to gather data was just too time consuming.

In this posting, the rarely-used "USER" table in the active project's database file will illustrate results of pushing certain extended entity data (i.e. "Xdata") out to non-opened project drawings. This data then automatically flows into the USER table and is immediately available (with a very short time delay) for project-wide queries and tasks.

What is the project scratch database's USER table?

Extended entity data (Xdata) assigned to wire numbers, schematic components and terminals, and panel footprints and panel terminals is automatically pulled into this table IF the Xdata appname is in this format:

VIA_WD_USERnnn

... where nnn = 000 through 199. The data pulled into the table is limited to 255 character values. This means that a single wire number or component inserted into any drawing of the project can have up to 200 of these VIA_WD_USERnnn Xdata values, each with 255 characters, and have all of this data automatically maintained in the project scratch database USER table.

What data should be pushed into these Xdata value assignments? That's up to you!

Example... let's say that you want to remember connecting wire lug / ferrule assignments for certain component terminal pin connections. Here are the three motor starter contacts related to motor starter coil M414. Let's say that we want to mark each of these three child symbols with some wire connection "lug" assignment.

Each component symbol (i.e. block insert) on this drawing carries an AutoCAD "handle" assignment (automatically assigned by the AutoCAD drawing editor as the block insert instance is popped into the schematic). For example, the bottom child contact's handle assignment is "2A0". Remember this. It will be used to link things up a bit later.

The Example Xdata Assignment / Editor utility

Launching the attached utility pops up this opening dialog. This lists all drawings in the current, active project. You pick which drawing and what component category to process. Here we'll select the DEMO02 drawing and "Schematic components".

The utility queries the COMP table in the active project's scratch database file and finds all schematic components that are on the selected DEMO02 drawing (via query on field DWGIX). This dialog immediately displays:

Now we pick on the three child instances of M414 and add some proposed Xdata values. Let's say that the first Xdata value will be for the component's first "01" wire connection and the second for the "02" wire connection.

After making the proposed assignments for the three child contacts, the dialog displays above. The Xdata has not yet been written out to the un-opened DEMO02.dwg drawing file. It is written as soon as select the "Save changes" button.

At this point, the utility runs through this part of its program:

(if (not cancel3)

(progn ; save this block of data to target drawing

    (setq changed nil)

    (princ "\nWriting Xdata changes back to drawing...")

    ; Open the drawing file

    (setq filehdl (wd_dbx_open picked_dwgnam "w"))

    (foreach rec comp_plus_user_data_lst

      ; rec = (list compdata user_lst_for_this_comp oldvals newvals)

      ; The 3rd and 4th elements only present if the xdata was

      ; edited for the given component.

      (if (= (length rec) 4)

        (progn

          (setq compdata (nth 0 rec)) ; DWGIX,INST,LOC,HDL,TAGNAME

          (setq hdl (substr (nth 3 compdata) 3)) ; strip off the "h=" prefix

          (setq user_lst_for_this_comp (nth 1 rec))

          (setq oldvals (nth 2 rec)) ; values 000 through 009

          (setq newvals (nth 3 rec))

          ; Compare old and new values for each of the USERxxx

          ; entries. On a change, go ahead and push the new

          ; value out to the target component (via its handle)

          (setq ix 0)

          (foreach new newvals

            (if (not old)

              (setq old nil)

            ; ELSE

              (setq old (nth ix oldvals))

            )

            (if (AND new (/= new old))

              (progn ; different, push it out

                (setq str (itoa ix))

                (cond

                  ((< ix 10)(setq str (strcat "USER00" str)))

                  ((< ix 100)(setq str (strcat "USER0" str)))

                )

                ; Push this xdata value out to the target component (via its

                ; "hdl" handle) on the opened dwg file (file handle "filehdl").

                ; Xdata tag name is "VIA_WD_USER"

                (wd_1b_mod_1000_xdata filehdl hdl (strcat "VIA_WD_" str) new T)

                (setq changed T)

                (princ "\n")(princ (nth 4 compdata))(princ " (")

                (princ hdl)(princ ") ")

                (princ (strcat "VIA_WD_" str))

                (princ "=")

                (princ new)

            ) )

            (setq ix (1+ ix))

          )

      ) )

    )

    (if changed

      (progn ; close the drawing and save changes

        (princ "\n")

        (wd_dbx_close filehdl T)

      )

    ; ELSE

      (progn ; no xdata written to this drawing file.

             ; Close with "no save"

        (wd_dbx_close filehdl nil)

    ) )

    (setq filehdl nil)

)

The highlighted lines are key. These enable the Xdata values to be written out to the target components on the un-opened AutoCAD drawing file. This seems to work fine on ACE2008 through ACE2010. Did not try other versions.

In a few moments, AutoCAD Electrical's normal auto-freshen of the project scratch database will sense that drawing DEMO02.dwg time/date stamp has changed and its data needs to be "freshened". Suddenly these Xdata assignments show up in the USER table ( ! )

The link between the component's records in the USER table and the component's records in the COMP table can be established via match-ups with the DWGIX and HDL field values.

Note: There is potential for confusion. The "nnn" part of the VIA_WD_USERnnn xdata name is zero-based but when it is extracted into the USER table, the "SUFFIX" value is one-based. This means that USER000 will map to suffix 001 in the USER table, USER001 to 002, ... USER199 maps to 200.

Conclusion

So, there it is. You can push custom data to components on filed drawings and then have that data automatically show up on the project's scratch database file.

Download sample utility here

files/29101_29200/29171/file_29171.dcl - rename USER_TABLE_DEMO.DCL and put it into any AutoCAD Electrical support folder

files/29101_29200/29181/file_29181.lsp - rename USER_TABLE_DEMO.LSP

To run: APPLOAD the lsp file. Then type USER_TABLE_DEMO [Enter] at the "Command:" prompt.

This sample utility seems to work in either SDI or MDI mode.

AutoCAD Electrical's report customization - the 'User Post'

Mon, 15 Jun 2009 12:53:00 -0700

We've posted a number of times with specific examples of report 'User Posts'. Here is another but one that is given in much greater detail. This posting might better serve as template for creating your own customizations of AutoCAD Electrical's reports.

The Challenge

A European dealer had a customer who wanted his Cable From/To report to repeat the parent cable marker's catalog assignment for each and every child entry in the report.

For example, here is how a portion of the default report displays.

The problem for this user is that he wants to see the cable's catalog assignment show up for EVERY core/conductor displayed, not just the first 'parent' entry for the cable.

In the highlighted section above for cable tag-ID '-W5', the parent core/conductor carries the MFG/CAT catalog assignment (parent = 1 in the CBLP1C2 column). This shows up for the one line in the report for cable -W5. But the remaining child core/conductors (child = 2 in CBLP1C2 column) do not carry the parent's assignment and therefore their entries in the report show blank for the catalog assignment.

The customer wants all these filled in.

One work-around is to put the same catalog assignment on each child core/conductor of the cable. This will solve one problem (our Cable From/To report) but will then totally confuse the Bill of Materials report... we'll get a full cable BOM entry for every conductor/core found in a cable.

So, the only reasonable work-around is to create a "user post".

The Default User Post for the Cable From/To Report

There is a default user post AutoLISP utility for each AutoCAD Electrical report type. There is one for this Cable From/To report.

So, when the normal Cable From/To report displays, the user selects the "User Post" button on the lower right-hand corner of the report dialog.

This launches an AutoLISP utility "cablecon.lsp" and passes the block of report data (in form of "list of lists") to this cablecon.lsp utility. The location of this user post program file is displayed in the command window (shown below for ACE2008, subsequent releases have it in "c:\documents and settings\All Users\Documents\Autodesk\Acade 200x\Support\"). This user post utility immediately fires up and displays an options dialog as shown here.

Our challenge is to add a fourth option to this dialog: "Display catalog assignments on child entries"

Step 1 - Modify the dialog "DCL" file

Open the file cablecon.dcl with any ASCII text editor. This file should be in the same folder as the user post utility (path shown in command window above).

Make a back-up copy. Then carefully modify the original version. Add the fourth option as shown below and save the modified file.

That should now trigger a fourth toggle to display when the Cable From/To User Post is run. But this new toggle is not "hooked up" to anything. That's the next [more complicated] step.

Step 2 - Modify the cablecon.lsp file

Open up this file (path given above) with an ASCII text editor or with the Visual Lisp editor built into AutoCAD / AutoCAD Electrical. Page down a bit to the "main routine" section shown below. Add in the two lines of code as marked. These two lines make the initial link into the new toggle added to the dialog definition file in Step #1.

Now the meat of the addition...!

Page down to near the bottom of the cablecon.lsp file. Insert the new section as shown here:

Here is how the above is meant to work...

When the user selects the 4th toggle on the opening DCL dialog, it sets the "user_4" flag to a value of "1". This triggers this highlighted section of the utility to execute. The first "foreach..." makes an initial pass through each line of passed report data (in list "wd_rdata"). Here is how this first pass works, but a bit of explanation needed first.

The format of the report data is a list of sublists. Each sublist represents the data for a line in the report. Each line's sublist has about 70 or so elements. What each element means is given in a comment section shown at the top of the user post cablecon.lsp file and is reproduced below.

; -- Structure of the "wd_rdata" list of lists passed from ACE:

;

; (list (list ) (list ) ... )

; where each line data sublist consists of a list of the following:

; 0 = wire number

; 1 = LOC for "from" device

; 2 = TAG ID for "from" device

; 3 = terminal PIN number for "from" device connection

; 4 = LOC for "to" device

; 5 = TAG ID for "to" device

; 6 = terminal PIN number for "to" device connection

; 7 = WIRELAY for wire touching "from" device

; 8 = WIRELAY for wire touching "to" device

; 9 = line ref of "from" device

; 10= line ref of "to" device

; 11= SHEET number for "from" device

; 12= SHEET number for "to" device

; 13= cable marker - TAG ID (if cable marker present in wire)

; 14= cable marker - conductor color/number value

; 15= cable marker - LOC code

; 16= cable marker - MFG part number assignment

; 17= cable marker - CAT part number assignment

; 18= cable marker - ASSYCODE part number assignment

; 19= cable marker - catalog lookup DESC field value

; 20= cable marker - catalog lookup QUERY1 field value

; 21= cable marker - catalog lookup QUERY2 field value

; 22= cable marker - catalog lookup MISC1 field value

; 23= cable marker - catalog lookup MISC2 field value

; 24= cable marker - catalog lookup USER1 field value

; 25= cable marker - catalog lookup USER2 field value

; 26= cable marker - catalog lookup USER3 field value

; 27= cable marker - DESC1 description value assignment

; 28= cable marker - DESC2

; 29= cable marker - DESC3

; 30= cable marker - 1=parent marker, 2=child marker

; 31= TAG:PIN - combined "from" device text consisting of TAG ID and PIN number

; 32= TAG:PIN - combined "to" device text consisting of TAG ID and PIN number

; 33= SEC assignment for drawing with "from" device

; 34= SUBSEC assignment for drawing with "from" device

; 35= SEC assignment for drawing with "to" device

; 36= SUBSEC assignment for drawing with "to" device

; 37= INST assignment of "from" device

; 38= INST assignment of "to" device

; 39= IEC style name for "from" device

; 40= IEC style name for "to" device

; 41= TERMDESC value of "from" device wire connection point

; 42= TERMDESC value of "to" device wire connection point

; 43= wire connection sequence code for "from" device wire connection

; 44= wire connection sequence code for "to" device wire connection

; 45= PNLWDLEV1

; 46= PNLWDLEV2

; 47= CMPHDL1 = handle of the "from" component

; 48= CMPHDL2 = handle of the "to" component

; 49= DWGIX1 = the "from" component's drawing index number

; 50= DWGIX2 = the "to" component's drawing index number

; 51= DWGNAM1 = the %D drawing name value of the "from" drawing

; 52= DWGNAM2 = the %D drawing name value of the "to" drawing

; 53= handle of the cable marker

; 54= INST of the cable marker

; 55= CBLDWGIX drawing index number of the cable marker

; 56= entity name of the connected wire on "from" component

; 57= entity name of the connected wire on "to" component

; 58= wire connection direction of "from" component wire connection

; 59= wire connection direction of "to" component wire connection

; 60-62 = X,Y,Z of any associated "from" panel layout wire connection

; 63= "from" panel footprint representation wire connection direction

; 64-66 = X,Y,Z of any associated "to" panel layout wire connection

; 67= "to" panel footprint representation wire connection direction

; 68 = estimated wire length based upon 60-62 and 64-66

So, our first pass needs to look for parent entries (index 30 in the sublist) that have non blank catalog assignments (index 17 in the sublist). For each one found in the first pass, it saves that line of data in a variable called "parent_lst".

Now, with all parent cable markers found, the utility makes a second pass through the lines of report data. It looks for "child" cable marker entries (value of "2" in the 30th index position) and makes sure that the child entry has no current assignment (the index 17 position is blank).

For each hit, it quickly looks for a parent match (from the "parent_lst" list collected in the first pass). If match on tag-ID and INST and LOC, then it pulls a copy of the parent's MFG/CAT/ASSYCODE and pushes it into the child's sublist (index positions 16,17, and 18).

The second pass builds a new, fresh copy of the list of sublists for the report (built in the variable called "rtrn"). The parent entries and children that have no parent match get pushed back into this new version of the data "as is". But the child entries that find a match get their modified version pushed into "rtrn". The version last line shown above replaces the original "wd_rdata" list of data with this modified version.

This new version of the report data is returned back to the report display dialog. That's about it. The dialog will now display the child entries with the MFG/CAT values filled in ( ! )

Mass update - attribute re-namer tool - AutoCAD Electrical

Thu, 21 May 2009 03:32:35 -0700

This came up recently. It's not a perfect solution but seemed to make the user happy. He had a number of old schematic designs made with generic blocks with attributes. He wanted some AutoCAD Electrical compatibility for simple things like BOM reporting.

The key is to rename the attributes to be those that AutoCAD Electrical expects to find. Here is a utility that seems to work. It process all block inserts on the active drawing. For each block it scans the block for all its attributes. It compares each attribute to a list of "old" names. On a match it gets the corresponding new name and renames the attribute on-the-fly.

Seems to work!

This AutoLISP program is reproduced here. The old versus new attribute name list is in the top part of the program. Edit this file and replace the old/new attributes appropriately. Save the file, APPLOAD it, and run it!

; 20-May-09 NEHolt created

(defun c:attr_rename_list ( / x_en enn edd ss slen ix atnam

           namelist hit blk_ent

           matchname newed x)

; Process all block instances on active drawing. Check each

; attribute for match on first element in list below. On any

; match, rename the attribute to the new name given in the

; second element.

; ***********   ATTRIBUTE OLD versus NEW names list   ******************

(setq namelist (list

      ; list old name and new name. Old name can contain wild cards.

      (list "ID" "TAG1") ; list old name and new name.

      (list "TEXT-1" "DESC1")

      (list "TEXT-2" "DESC2")

      (list "TERMINAL1" "TERM01")

      (list "TERMINAL2" "TERM02")

      (list "PARTNUM" "CAT")

      (list "VENDOR" "MFG")

) )

; **********************************************************************

; Extract selection set of all block inserts on active drawing

(setq ss (ssget "_X" '((0 . "INSERT"))))

(if (/= ss nil)

    (progn

      (setq slen (sslength ss))

      (setq ix 0)

      (while (< ix slen)

        (setq blk_ent (ssname ss ix)) ; get next block insert to process

        (setq ix (1+ ix)) ; increment for next time

        (setq enn (entnext blk_ent))

        (setq edd (entget enn))

        (while (AND enn (/= (cdr (assoc 0 edd)) "SEQEND")

                            (/= (cdr (assoc 0 edd)) "INSERT") )

          (if (= (cdr (assoc 0 edd)) "ATTRIB")

            (progn

              (setq atnam (cdr (assoc 2 edd)))

              (setq hit nil)

              (foreach x namelist

                (if (not hit)

                  (progn ; no match yet, keep processing

                    (setq matchname (car x))

                    (if (wcmatch atnam matchname)

                      (progn ; found exact match or wild-card match

                        ; Change name now. Substitute in new name.

                        (setq newed (subst (cons 2 (cadr x)) (assoc 2 edd) edd))

                        (entmod newed) ; update the title block instance

                        (entupd blk_ent)

                        (princ "\n")

                        (princ atnam)

                        (princ " --> ")

                        (princ (cadr x))

                        (setq hit 1) ; flag that found

                ) ) ) )

              )

            )

          )

          ; go to next sub ent in block instance and loop back up

          (if (setq enn (entnext enn)) (setq edd (entget enn)))

      ) )

      (setq ss nil) ; release the selection set

    )

)

(princ) ; prettier

)

Download a copy of the utility here: files/27801_27900/27811/file_27811.lsp

Rename it to something like attr_rename_list.lsp. Then to run it, APPLOAD this file and type attr_rename_list [Enter] at the AutoCAD command prompt.

Index to 100+ AutoCAD Electrical Utilities

Tue, 14 Apr 2009 17:36:00 -0700

This blog's three years went quickly. It's been fun. I really appreciate the privilege to (try to) respond to your questions and suggestions.

About a six months ago I posted a simple index to the 86 or so utilities that had been published on this blog in its first year. Now, we're up to about 108, so here's an updated list (starting with most recent).

IEC-style Wire Numbering - AutoCAD Electrical

Mon, 13 Apr 2009 18:48:00 -0700

Though not a specific option, IEC-style wire numbering with suppression of INST and LOC prefix values when match drawing defaults is possible. The work-around is described below.

The driving force behind this request comes from Miles Nicholson, Aceri UK. His customers often must deal with dozens of repeated, cookie-cutter circuits where wire numbers are to be the same from instance to instance - though the different wire networks with a common wire number are not connected.

A good example might be repeated, standard circuits found in motor control center documentation. Each circuit is contained within its own "cubical" of the MCC with only a few control wire connections leaving it to go elsewhere. Here is what the customer wants to see for wire numbering:

The Problem

Assuming that there are a dozen drawings in the project, each with a circuit as shown above (but with different motor numbers), there are going to be twelve wire number 9's in the project set, twelve wire number 11's in the drawing set, twelve motor leads labeled 2 in the drawing set. AutoCAD Electrical is not going to want to repeat wire numbers.

Miles' Solution - Step 1

The first step of the solution is to set up AutoCAD Electrical to add an IEC-style "INST/LOC" prefix to each wire number. The INST and LOC values can be set up as drawing-wide defaults from "Drawing Properties" dialog. For example, the INST value might be "MCC2" to designate that the drawing is associated with Motor Control Center #2. The LOC assignment might be the circuit's cubical location within MCC2. For example, LOC = "C4" might mean that is it in the third vertical section ("C") and the fourth position down from the top (i.e. "4").

So, for each drawing (one MCC cubical circuit per drawing), the drawing INST/LOC defaults are set up to identify the MCC "installation" and the cubical "location" within the MCC.

Now, on this same Drawing Properties dialog, Miles sets the wire numbering format to include the IEC "Inst" and "Loc" flags (%I and %L) as a prefix to the generated wire number (the %N part of the wire number tag format).

Now, with all this in place for each drawing that has a cubical schematic drawing, we're ready to do project-wide wire numbering. Since each drawing's INST/LOC combo is unique and each drawing is set to sequential wire numbering starting at "1", Miles ends up with common wire numbering for each circuit except for the INST/LOC prefix. Here is one of the drawings with the unique "=MCC2+C4" prefix on all of the assigned wire numbers.

Step 2 - Stripping off the LOC and/or INST prefix when match drawing defaults

Final step requires a small AutoLISP function that makes a number of calls into the AutoCAD Electrical "API". This little tool will process one drawing at a time. It will read the drawing's default INST and LOC assignments (what user previously entered from Drawing Properties dialog and saved on the WD_M block). Then it will process each wire number it finds. It looks for a wire number match on the INST value. If found, it strips that part off of the wire number. Then it does the same for the LOC value. If match, it strips off that too.

The net result is that any wire number that exactly matches the drawing default's INST/LOC values will end up being restored to a bare wire number. But any wire number that comes from some other location (i.e. will have a different INST/LOC prefix combo), will remain unchanged ( ! ). Pretty cool.

Here is the little AutoLisp utility. Note that you can modify this utility to either work on all wire numbers or on just those that are not marked "fixed". Comment out the appropriate line, about 18 lines down.

; ** 12-Apr-09 NEHolt reworked to look for drawing-wide INST/LOC assignments

; ** 16-Feb-08 NEHolt fixed typo in original

; ------- W N U M _ R M V _ I E C _ S U F F I X . L S P ------

(defun c:rmv ( / ss delim_char slen ix wnum_en pos wen newnum attrname)

; PURPOSE: remove IEC wire number suffix when INST/LOC values match up

;   with drawing-wide INST/LOC assignments... leaving just bare wire number.

;   This works on both normal wire numbers and in-line wire numbers. It updates

;   any extra wire number "copies" as well.

;   Note: this will process and modify just "normal" (i.e. non-fixed) wire numbers

;     unless adjustment made immediately below.

; ************

; To process both normal and "fixed" wire numbers, uncomment line "WIRENO*" and

; comment out the "WIRENO" line.

; To process just "normal" wire numbers and leave "Fixed" untouched, uncomment

; the "WIRENO" line below and comment out the "WIRENO*" line.

; (uncomment just one of the two lines below - remove the line's leading ";" character)

; (setq attrname "WIRENO*") ; uncomment this line to process both normal and fixed

(setq attrname "WIRENO") ; uncomment this line to process just "normal" (fixed untouched)

; ************

; Search for schematic wire number instances. This includes in-line wire number

; instances.

(setq ss (ssget "_X" '((-4 . "
                         ( 0 . "INSERT")

                         ( 2 . "WD_WN*")

                         (-4 . "AND>"))))

(if (/= ss nil)

    (progn ; active drawing carries some wire number instances. Continue.

      ; Get drawing-wide INST and LOC assignments

      (wd_cfg_read_dwg_params) ; read the WD_M block and set GBL_wd_m global

      (setq inst (nth 52 GBL_wd_m)) ; get INST from drawing properties

      (setq loc (nth 53 GBL_wd_m)) ; get LOC value from drawing properties



      (setq slen (sslength ss))

      (setq ix 0)

      (while (< ix slen)

        (setq wnum_en (ssname ss ix)) ; get wire number entity

        (setq ix (1+ ix)) ; increment for next time

        ; Get wire number text (either WIRENO* or WIRENO attribute name)

        (if (setq wnum_val (c:wd_getattrval wnum_en attrname))

          (progn

            (setq save_val wnum_val) ; save copy for comparison later

            (if (AND inst (/= inst ""))

              (progn ; Look for INST prefix on this wire number string

                (if (= (substr wnum_val 1 (strlen inst)) inst)

                  (progn ; Exact match with INST value. Strip it off

                    (setq wnum_val (substr wnum_val (1+ (strlen inst))))

                  )

                ; ELSE

                  (progn

                    (if (= (substr wnum_val 1 (1+ (strlen inst))) (strcat "=" inst))

                      (progn ; Exact match with "=INST" value. Strip it off.

                        (setq wnum_val (substr wnum_val (+ 2 (strlen inst))))

            ) ) ) ) ) )

            (if (AND loc (/= loc ""))

              (progn ; Look for LOC prefix on this wire number string

                (if (= (substr wnum_val 1 (strlen loc)) loc)

                  (progn ; Exact match with INST value. Strip it off

                    (setq wnum_val (substr wnum_val (1+ (strlen loc))))

                  )

                ; ELSE

                  (progn

                    (if (= (substr wnum_val 1 (1+ (strlen loc))) (strcat "+" loc))

                      (progn ; Exact match with "=INST" value. Strip it off.

                        (setq wnum_val (substr wnum_val (+ 2 (strlen loc))))

                    ) )

            ) ) ) )



            (if (/= wnum_val save_val)

              (progn ; Something was stripped off. Push bare wire number back

                     ; out to the wire network.

                ; Remove any leading "-" prefix on the wire number

                (if (= (substr wnum_val 1 1) "-")(setq wnum_val (substr wnum_val 2)))



                ; Now get the entity name of the wire that passes under this

                ; wire number instance.

                (if (setq wen (car (c:ace_wnum_find_wire_en wnum_en GBL_wd_trp)))

                  (progn ; Found it. Push revised wire number back out. Update

                         ; any extra wire number "copies" found on the wire network.

                    (princ "\n")

                    (princ save_val)

                    (princ " --> ")

                    (princ wnum_val)

                    (c:wd_putwn wen wnum_val)

        ) ) ) ) ) )

      )

      (setq ss nil)

    )

)

(princ)

)

Download it here. files/26701_26800/26711/file_26711.lsp Copy it to some folder that is in your ACAD support path and rename it wnum_rmv_iec_suffix.lsp.

To make it always available, follow the instructions that Miles shows here:

Type Appload at the command prompt.

Under the section StartUpSuite, select Contents

Select Add

Browse to the folder where you downloaded the above file.

Pick the file wnum_rmv_iec_suffix.lsp

Select Add and then Close

Now, any time you need the tool to operate on the active drawing, type RMV [Enter] at the command line. You can also run this tool in a project-wide mode. To do this, create a script file with just a single line entry "RMV". Then reference this script file from the "Project-wide Utilities" --> "Run Command Script" edit box.

Quick Customize Right-Click Menus - AutoCAD Electrical

Fri, 10 Apr 2009 17:48:23 -0700

User emails... placement of the "Delete" component command is right next to "Edit" component on the context-sensitive right-click menu. Too often, for this user, the component disappears when user expecting the edit dialog to appear ( ! )

Here's the User's Problem

Right-clicks on a selector switch to do a quick edit. Context menu pops up. User lunges for "Edit Component" but gets the button right above it instead. Selector switch disappears ( ! ).

The Quick Fix

Let's isolate this context menu's "Delete Component" button a bit. Make it is less likely to be selected by mistake.

Launch the CUI command. Just type CUI [Enter] at the AutoCAD Electrical command line prompt. This dialog appears:

Find the "Electrical" category and expand the "Shortcut Menus". Then expand the "Hot Wire menu only - Schematic components" as shown here:

There's our "Delete Component" entry, sandwiched between "Copy" and "Edit". What can we do about this?

Solution #1 - Let's put a bit of extra space above and below it in the menu.

Right click on the "Delete Component" entry and select "Insert Separator". Right click on the "Copy Component" and do the same. This will insert a line separator below and above the "Delete Component" entry.

Now hit OK to dismiss the CUI dialog. Let's try it. Right click on the selector switch now shows the "Delete Component" a bit better separated from the other commands.

We like this. But now that we know we can do stuff like this, we want even more.

Solution #2 - move this command to bottom with even more isolation.

Restart the CUI command. Highlight the "Erase Component" command entry and drag it down to near the bottom of the menu's command list. Add in double sets of "Separators".

Hit OK. Test again. Yes, much better!!!

Autodesk Assistance Program

Mon, 06 Apr 2009 15:04:00 -0700

The Autodesk Assistance Program is being launched in North America for unemployed workers in the architecture, engineering, design and manufacturing communities to update their skills and improve their employability in a down economy.

Autodesk Assistance Program tools and resources will be made available through an online portal where users can access:

1. Free (per terms and conditions of the end-user license agreement that accompanies the software) 13-month term student license of AutoCAD, Autodesk Revit Architecture, Autodesk Inventor Professional, and/or AutoCAD Civil 3D software.

2. Free Online Training - on-demand training through vBooks (internet access required)

3. Reduced-cost Classroom Training

4. Certification - discounted rates through Autodesk AUthorized Certification Centers.

Please access this link for details: www.autodesk.com/pr-assistanceprogram

FAQ: students8.autodesk.com/ama/orig/Autodesk_Assistance_Program_Customer_FAQ-_FINAL.pdf