; ** 13-Jun-07 NEHolt; created
; -------------   C B L _ N O _ W N U M . L S P  -----------
; PURPOSE: Erase wire numbers on any networks that also include
; a parent or child cable marker.
(defun c:cbl_no_wnum ( / ss pntlst wire lst ix)
  ; Process all of active drawing. Find all cable marker
  ; symbols using wild-card search on the block name.
  (setq ss (ssget "_X" '((-4 . "<AND")
                         (0 . "INSERT")
                         (2 . "?W01*,?W02*")
                         (-4 . "AND>"))))
  (if (/= ss nil)
    (progn ; some found, okay to continue
      ; Do ZOOM EXTENTS so that processing below can fully
      ; "see" the network on screen.
      (command "_.ZOOM" "_E")
      ; Number of cable block inserts to process
      (setq slen (sslength ss))
      (setq ix 0)
      (while (< ix slen)
        ; Get next cable block insert entity name        
        (setq cbl_en (ssname ss ix))
        ; Find wire connection points and connected
        ; wires
        (setq pntlst (c:wd_get_sym_pntlst cbl_en nil nil))
        ; Process wire connections that tie to this
        ; cable marker
        (foreach lst pntlst
          ; Get connected wire's entity name
          (setq wire (car (nth 3 lst))) 
          ; Delete any wire numbers, wire number
          ; copies, wire number leaders found on
          ; this wire network
          (if wire (c:ace_del_wnum wire))
        )
        ; Increment index to go to next block insert
        ; in the selectino set
        (setq ix (1+ ix))
      )
      ; All done
      (setq ss nil)
      ; Restore original zoom
      (command "_.ZOOM" "_PREV")
    )
  )
  (princ)
)